How to parse multiples lines from StringList-CodePudding

I want to copy specific lines from a StringList, I want to copy all lines that have 'Domain Status:' into memo.lines.text I used the code below, but the problem is it copies only the first line, I want to copy all lines that have 'Domain Status:':

 const
 FieldNames: array[0..2] of string = ('Domain Status', 'domain status', 'Domain status');
 begin
  sl := TStringList.Create;
  try
    sl.Assign(Memo.Lines);
    for I := 0 to sl.Count-1 do begin
      sl[I] := TrimLeft(sl[I]);
    end;
    sl.NameValueSeparator := ':';
    for I := Low(FieldNames) to High(FieldNames) do begin
      status := Trim(sl.Values[FieldNames[I]]);
      if status <> '' then Break;
    end;
  finally
    sl.Free;
  end;
  memo1.lines.text:=status;

Example of text in the StringList :

Domain Name: yahoo.com
Registry Domain ID: 3643624_DOMAIN_COM-VRSN
Registrar WHOIS Server: whois.markmonitor.com
Registrar URL: http://www.markmonitor.com
Updated Date: 2022-03-09T15:51:45 0000
Creation Date: 1995-01-18T08:00:00 0000
Registrar Registration Expiration Date: 2023-01-19T05:00:00 0000
Registrar: MarkMonitor, Inc.
Registrar IANA ID: 292
Registrar Abuse Contact Email: [email protected]
Registrar Abuse Contact Phone:  1.2083895770
Domain Status: clientUpdateProhibited (https://www.icann.org/epp#clientUpdateProhibited)
Domain Status: clientTransferProhibited (https://www.icann.org/epp#clientTransferProhibited)
Domain Status: clientDeleteProhibited (https://www.icann.org/epp#clientDeleteProhibited)
Domain Status: serverUpdateProhibited (https://www.icann.org/epp#serverUpdateProhibited)
Domain Status: serverTransferProhibited (https://www.icann.org/epp#serverTransferProhibited)
Domain Status: serverDeleteProhibited (https://www.icann.org/epp#serverDeleteProhibited)
Registrant Organization: Yahoo Assets LLC
Registrant State/Province: VA

I would like to get :

clientUpdateProhibited
clientTransferProhibited
clientDeleteProhibited
serverUpdateProhibited
serverTransferProhibited
.....
without the http://www.icann.org...

CodePudding user response：

You need to loop through the individual strings of the TStringList, the TStringList.Values[] property will not help you with this task, as it will only search for the 1st string with a matching name. You can, however, use the TStringList.Names[] and TStringList.ValueFromIndex[] properties to help you.

Also, you don't need the FieldNames[] array at all. Use a case-insensitive comparison, like SysUtils.SameText() instead.

Try something more like this:

sl := TStringList.Create;
try
  sl.Assign(Memo.Lines);
  sl.NameValueSeparator := ':';
  for I := 0 to sl.Count-1 do begin
    sl[I] := TrimLeft(sl[I]);
    if SameText(sl.Names[I], 'Domain Status') then begin
      status := Trim(sl.ValueFromIndex[I]);
      status := Copy(status, 1, Pos(' ', status)-1);
      Memo1.Lines.Add(status);
    end;
  end;
finally
  sl.Free;
end;

CodePudding user response：

Another approach is to use regular expressions. A bit overkill but if you can keep the regular expression around instead of recreating it with each use performance can be comparable.

procedure TForm1.Button1Click(Sender: TObject);
Var
    RegExDomainStatus : TRegEx;
    Match : TMatch;
    Alltext : string;
begin
  RegExDomainStatus.Create('(?<=^domain status: )[A-z] ',[roIgnoreCase,roMultiline]);
  Alltext := Memo1.Lines.Text;
  Memo1.Lines.Clear;
  match :=  RegExDomainStatus.Match(AllText);
  while match.Success do
  begin
     memo1.Lines.add(match.Value);
     match := match.NextMatch;
  end;
end;