Inserting select-case for different e-mail addresses

i am trying to create a vba-outlook-macro which saves attachments (mostly pdfs) automatically with a click of a button. I have finished code which does the job nicely, but our team in freight-management wants that depending from which e-mail address the customer e-mail with the attachment came from to save in a customer specific folder (Change strFolderpath depending of case). I want to use the select-case method for that matter for easier changes and additions in the future, but i'm stuck right now. Does somebody of you have a solution, how to add the select-case method for that use-case? I tried multiple alterations but nothing worked.

I hope some of you can help me. My working code is down here:

Sub SaveAttachments()
Dim objOL As Outlook.Application
Dim objMsg As Outlook.MailItem 'Object
Dim objAttachments As Outlook.Attachments
Dim objSelection As Outlook.Selection
Dim i As Long
Dim lngCount As Long
Dim strFile As String
Dim strFolderpath As String
Dim strDeletedFiles As String

' Instantiate an Outlook Application object.
Set objOL = CreateObject("Outlook.Application")

' Call the Namespace to see the sender e-mail address.
Set objNamespace = objOL.GetNamespace("MAPI")

' Get the collection of selected objects.
Set objSelection = objOL.ActiveExplorer.Selection

' Set the Attachment folder.
strFolderpath = "C:\Folder\Test\"

' Check each selected item for attachments. If attachments exist,
' save them to the strFolderPath folder and strip them from the item.
For Each objMsg In objSelection

    ' This code only strips attachments from mail items.
    ' If objMsg.class=olMail Then
    ' Get the Attachments collection of the item.
    Set objAttachments = objMsg.Attachments
    lngCount = objAttachments.Count
    strDeletedFiles = ""

    If lngCount > 0 Then

        ' We need to use a count down loop for removing items
        ' from a collection. Otherwise, the loop counter gets
        ' confused and only every other item is removed.

        For i = lngCount To 1 Step -1

            ' Save attachment before deleting from item.
            ' Get the file name.
            strFile = objAttachments.Item(i).FileName

            ' Combine with the path to the Temp folder.
            strFile = strFolderpath & strFile

            ' Save the attachment as a file.
            objAttachments.Item(i).SaveAsFile strFile

            ' Delete the attachment.
            objAttachments.Item(i).Delete

            'write the save as path to a string to add to the message
            'check for html and use html tags in link
            If objMsg.BodyFormat <> olFormatHTML Then
                strDeletedFiles = strDeletedFiles & vbCrLf & "<file://" & strFile & ">"
            Else
                strDeletedFiles = strDeletedFiles & "<br>" & "<a href='file://" & _
                strFile & "'>" & strFile & "</a>"
            End If

            'Use the MsgBox command to troubleshoot. Remove it from the final code.
            'MsgBox strDeletedFiles

        Next i

        ' Adds the filename string to the message body and save it
        ' Check for HTML body
        If objMsg.BodyFormat <> olFormatHTML Then
            objMsg.Body = vbCrLf & "The file(s) were saved to " & strDeletedFiles & vbCrLf & objMsg.Body
        Else
            objMsg.HTMLBody = "<p>" & "The file(s) were saved to " & strDeletedFiles & "</p>" & objMsg.HTMLBody
        End If
        objMsg.Save
    End If
Next

ExitSub:

Set objAttachments = Nothing
Set objMsg = Nothing
Set objSelection = Nothing
Set objOL = Nothing
Set objNamespace = Nothing
End Sub

CodePudding user response：

You will need the Select Case to be within the For Each objMsg loop (incidentally you could also use an If statement if you're struggling with Case syntax).

For Each objMsg In objSelection
    Select Case True
        Case objMsg.SenderEmailAddress = "[email protected]"
            strFolderpath = "C:\Folder\sender1folder\"
        Case objMsg.SenderEmailAddress like "*domain.com"
            strFolderpath = "C:\Folder\otherfolder\"
        Case Else
            strFolderpath = "C:\Folder\Test\"
    End Select

    'rest of loop carry on here

CodePudding user response：

I want to use the select-case method for that matter for easier changes and additions in the future, but i'm stuck right now

It is not necessary to use the select case operator. The very first thing you need to do is to get the sender's SMTP address in the code and only then you can decide which path is to use.

To get the SMTP address instead of Exchange one (X500) you can try to get an Exchange user using the AddressEntry.GetExchangeUser method and then try to retrieve the ExchangeUser.PrimarySmtpAddress property value.

Read more about that in the HowTo: Convert Exchange-based email address into SMTP email address article.

After you have retrieved the SMTP address you could analyze the content and choose the appropriate folder for saving attachments.