Trying to extract worksheets from excel and save into separate workbooks-CodePudding

My workbook has 10 sheets, i am trying to extract worksheets and store them separately into their own workbooks. So for 10 Sheets there would be 10 workbooks.

I am using the code below, it extracts only one worksheet and gives an error.

Error

Object required (Error 424)

Code

Sub worksheettonewworkbook()

Dim ws As Worksheet
Dim wb As Workbook
Dim path As String

path = "C:\Users\username\Desktop\VBA\WorkbookExtraction"

For Each ws In ThisWorkbook.Worksheets
    Set wb = Workbooks.Add
    wb.SaveAs path & "\" & ws.Name
    ws.Copy before:=wb.Worksheets(1)
    wd.Close.savechanges = True
Next ws
End Sub

CodePudding user response：

Please, try using the next adapted code:

Sub worksheettonewworkbook()
 Dim ws As Worksheet, path As String

 path = "C:\Users\username\Desktop\VBA\WorkbookExtraction\"

 For Each ws In ThisWorkbook.Worksheets
    ws.Copy 'it creates a new workbook with a single page (the copied one...)
    ActiveWorkbook.saveas path & ws.name & ".xlsx", xlWorkbookDefault
    ActiveWorkbook.Close , False
 Next ws
End Sub

CodePudding user response：

How about this?

Sub Copy_Every_Sheet_To_New_Workbook()
'Working in 97-2013
    Dim FileExtStr As String
    Dim FileFormatNum As Long
    Dim Sourcewb As Workbook
    Dim Destwb As Workbook
    Dim sh As Worksheet
    Dim DateString As String
    Dim FolderName As String

    With Application
        .ScreenUpdating = False
        .EnableEvents = False
        .Calculation = xlCalculationManual
    End With

    'Copy every sheet from the workbook with this macro
    Set Sourcewb = ThisWorkbook

    'Create new folder to save the new files in
    DateString = Format(Now, "yyyy-mm-dd hh-mm-ss")
    FolderName = Sourcewb.Path & "\" & Sourcewb.Name & " " & DateString
    MkDir FolderName

    'Copy every visible sheet to a new workbook
    For Each sh In Sourcewb.Worksheets

        'If the sheet is visible then copy it to a new workbook
        If sh.Visible = -1 Then
            sh.Copy

            'Set Destwb to the new workbook
            Set Destwb = ActiveWorkbook

            'Determine the Excel version and file extension/format
            With Destwb
                If Val(Application.Version) < 12 Then
                    'You use Excel 97-2003
                    FileExtStr = ".xls": FileFormatNum = -4143
                Else
                    'You use Excel 2007-2013
                    If Sourcewb.Name = .Name Then
                        MsgBox "Your answer is NO in the security dialog"
                        GoTo GoToNextSheet
                    Else
                        Select Case Sourcewb.FileFormat
                        Case 51: FileExtStr = ".xlsx": FileFormatNum = 51
                        Case 52:
                            If .HasVBProject Then
                                FileExtStr = ".xlsm": FileFormatNum = 52
                            Else
                                FileExtStr = ".xlsx": FileFormatNum = 51
                            End If
                        Case 56: FileExtStr = ".xls": FileFormatNum = 56
                        Case Else: FileExtStr = ".xlsb": FileFormatNum = 50
                        End Select
                    End If
                End If
            End With

            'Change all cells in the worksheet to values if you want
            If Destwb.Sheets(1).ProtectContents = False Then
                With Destwb.Sheets(1).UsedRange
                    .Cells.Copy
                    .Cells.PasteSpecial xlPasteValues
                    .Cells(1).Select
                End With
                Application.CutCopyMode = False
            End If


            'Save the new workbook and close it
            With Destwb
                .SaveAs FolderName _
                      & "\" & Destwb.Sheets(1).Name & FileExtStr, _
                        FileFormat:=FileFormatNum
                .Close False
            End With

        End If
GoToNextSheet:
    Next sh

    MsgBox "You can find the files in " & FolderName

    With Application
        .ScreenUpdating = True
        .EnableEvents = True
        .Calculation = xlCalculationAutomatic
    End With
End Sub

https://www.rondebruin.nl/win/s3/win007.htm